Forum Mac Peer

Code: Select all

global newContents
tell application "iTunes"
	set theP to library playlist 1
	set checked_these to {}
	set List_With_No_Art to {}
	set List_With_Partial_Art to {}
	
	display dialog "The process of wrangling each album and its tracks may take some time." & return & return & "If for some reason you wish to cancel this process you must Force Quit \"Albums Without Artwork\" by pressing" & return & "    Option + Command + Escape." buttons {"Cancel", "Proceed..."} default button 2 with icon 1
	
	-- get filename
	set file_name to (choose file name with prompt "Enter a name for the text file that will be created:" default name "Albums Without Artwork")
	if file_name is false then error number -128 -- cancel
	if file_name as string does not end with ".txt" then set file_name to ((file_name as string) & ".txt")
	
	set mylimit to my get_input("", 4)
	
	with timeout of 3000 seconds
		set ev to (get album of tracks of theP)
		set every_album to {}
		repeat with a in ev
			set a to a as string
			considering case
				if every_album does not contain a and a is not "" then
					copy a to the end of every_album
				end if
			end considering
		end repeat
	end timeout
	
	repeat with t from 1 to count of items of every_album
		set theArt to ""
		with timeout of 60000 seconds
			set thisAlbum to item t of every_album
			set all_albums_tracks to (get tracks of theP whose album is thisAlbum)
			set nmtrks to (count of items of all_albums_tracks) -- used below also
			if nmtrks is greater than mylimit then
				
				set c to 0 -- counter
				repeat with a from 1 to count of items of all_albums_tracks
					try
						if (exists artworks of item a of all_albums_tracks) then set c to c + 1
						if theArt is "" then set theArt to (get artist of item a of all_albums_tracks)
					end try
				end repeat
				if c = 0 then
					copy ("\"" & thisAlbum & "\" - " & theArt & return) to the end of List_With_No_Art
				else
					if c is less than nmtrks then copy ("\"" & thisAlbum & "\" - " & theArt & return) to the end of List_With_Partial_Art
				end if
				
			end if -- my limit
		end timeout
		
	end repeat
	
	set preamb to "Albums "
	if mylimit is not 0 then
		set s to "s"
		if mylimit is 1 then set s to ""
		set preamb to preamb & "[of " & (mylimit as string) & " track" & s & " or more] "
	end if
	set newContents to preamb & ("Without Artwork" & return & return)
	
	if List_With_Partial_Art is not {} then
		set newContents to newContents & "These albums contain SOME tracks with artwork:" & return & return & (List_With_Partial_Art as text) & return & return
	end if
	if List_With_No_Art is not {} then
		set newContents to newContents & "These albums have NO tracks with artwork:" & return & return & (List_With_No_Art as text) & return & return
	end if
	
	try
		copy (a reference to (open for access file_name with write permission)) to fileRef
		write newContents to fileRef
		close access fileRef
	on error errx number errNum
		close access fileRef
		display dialog "There has been an error creating the file:" & return & return & errx & return & "error number: " & errNum buttons {"Cancel"}
	end try
	tell me to activate
	beep
	beep
	delay 1
	beep
	set dMes to return & return & "Would you like to open the text file with TextEdit?"
	set myEnding to (display dialog "Done!" & dMes buttons {"Done", "Yes"} default button 2 with icon 1 giving up after 16)
	if gave up of myEnding is true or button returned of myEnding is "Yes" then
		tell application "TextEdit"
			activate
			try
				open (file_name as alias)
			on error errMs
				display dialog errMs buttons {"Cancel"}
			end try
		end tell
	end if -- button is "Done"
	
end tell

to get_input(addenda, defval)
	tell me to activate
	copy (display dialog "" & addenda & ¬
		"Ignore albums that contain this many tracks or fewer:" default answer ¬
		defval buttons {"No! Every album counts!", "Limit to my number"} default button 1) to result_of_dd
	if button returned of result_of_dd starts with "No" then return 0
	copy text returned of result_of_dd to text_returned
	--check for a whole number
	try
		(text_returned as integer)
	on error
		tell me to get_input("Enter only numbers..." & return & return)
	end try
	return text_returned as integer
end get_input